extends Node2D

var dragged = null

var server
var client_connection

onready var input = $Terminal/Control/Input
onready var output = $Terminal/Control/Output
onready var goal_repository = $Repositories/GoalRepository
onready var active_repository = $Repositories/ActiveRepository

func _ready():
	# Initialize level select.
	var options = $LevelSelect.get_popup()
	for level in list_levels():
		options.add_item(level)
	options.connect("id_pressed", self, "load_level")
	
	# Initialize TCP server for fake editor.
	server = TCP_Server.new()
	server.listen(1234)
	
	# Load first level.
	load_level(0)
	input.grab_focus()
	
func list_levels():
	var levels = []
	var dir = Directory.new()
	dir.open("levels")
	dir.list_dir_begin()

	while true:
		var file = dir.get_next()
		if file == "":
			break
		elif not file.begins_with("."):
			levels.append(file)

	dir.list_dir_end()
	levels.sort()
	return levels

func load_level(id):
	var levels = list_levels()
	
	var level = levels[id]
	var tmp_prefix = "/tmp/"
	var level_prefix = game.cwd + "/levels/"
	
	var goal_repository_path = tmp_prefix+"goal/"
	var active_repository_path = tmp_prefix+"active/"
	var goal_script = level_prefix+level+"/goal"
	var active_script = level_prefix+level+"/start"
	
	var description = game.read_file(level_prefix+level+"/description")
	$LevelDescription.bbcode_text = description
	
	# Danger zone! We're actually destroying stuff here.
	# Make sure that active_repository is in a temporary directory.
	var expected_prefix = "/tmp"
	if active_repository_path.substr(0,4) != expected_prefix:
		push_error("Refusing to delete a directory that does not start with %s" % expected_prefix)
		get_tree().quit()
	if goal_repository_path.substr(0,4) != expected_prefix:
		push_error("Refusing to delete a directory that does not start with %s" % expected_prefix)
		get_tree().quit()
	
	game.exec("rm", ["-r", active_repository_path])
	game.exec("rm", ["-r", goal_repository_path])
	
	construct_repo(goal_script, goal_repository_path)
	construct_repo(active_script, active_repository_path)
	
	goal_repository.path = goal_repository_path
	active_repository.path = active_repository_path
	
func construct_repo(script, path):
	var shell = Shell.new()
	shell.run("mkdir " + path)
	shell.cd(path)
	shell.run("git init")
	print(shell.run("source "+script))
	
func _process(delta):
	if server.is_connection_available():
		client_connection = server.take_connection()
		read_commit_message()
	
func read_commit_message():
	$CommitMessage.show()
	input.editable = false
	$CommitMessage.text = game.read_file(active_repository.path+"/.git/COMMIT_EDITMSG")
	$CommitMessage.grab_focus()

func save_commit_message():
	game.write_file(active_repository.path+"/.git/COMMIT_EDITMSG", $CommitMessage.text)
	print("disconnect")
	client_connection.disconnect_from_host()
	input.editable = true
	$CommitMessage.text = ""
	$CommitMessage.hide()
	input.grab_focus()